***Переменные***

D(1..5) – подчиненные

С(3, 1..5) – личное имущество. 1 есть, 0 нет.

С(5, 1..5) – бизнес. 1 есть, 0 нет.

P(1..5) – Количество акций фирмы

R(1..5) – Цена купленных акций R(I) = 100 \* rnd[0;1)

Z(1..5) – Дивиденды по акциям Z(I) = 20 \* rnd[0;1)

T(1..5) – развлечения затраты

I(1..5) – развлечения возможный доход

O(1..5) – развлечения вероятность успеха

S(3, 1..5) – цена покупки имущества S(3, I) = INT((2 + 5\*rnd[0;1))\*20\*5^I)

Q(3, 1..5) – цена продажи имущества Q(3,I) = INT(0.7\*S(3, I)\*(rnd[0;1) + 0.3)))

rnd – одна и та же

S(5, 1..5) – цена покупки бизнеса S(5, I) = INT((2 + 5\*rnd[0;1))\*20\*5^I)

Q(5, 1..5) – цена продажи бизнеса Q(5,I) = INT(0.7\*S(5, I)\*(rnd[0;1) + 0.3)))

W(1..5) – годовой доход бизнеса W(I) = INT(0.7\*S(3, I)\*(rnd[0;1) + 0.3))) \* (rnd[0;1) - 0.3)

rnd – одна и та же

E(1..5) – годовая зарплата подчиненного E(I) = 4500\*rnd[0;1) + 2000\*I

G(1..5) – срок страховки

L(1..5) – сумма страховки (не более суммы продажи Q(3))

T(1..5) – затраты на развлечение

I(1..5) – доход от развлечений

O(1..5) – шанс получить доход от развлечений

NN – стартовый год

N – сколько прошло лет

N1 – маркер позиции внутри года

N2 – возраст

N3 – дата смерти = 60+20\*rnd[0;1)

N4 – L+(5-L)\*rnd[0; 1] – маркер конца года

L – класс

H – счет в банке

A – наличка на руках

B – общественное положение (1..5)

S – сумма ссуды

NS – срок ссуды. NS = NS – J

S1 – проценты, под которые дали ссуду

U – годовые расходы

B3 – флаг, прошли выборы или нет (1 – прошли, 0 – нет)

P – сумма дивидендов

C – активы в личном имуществе и бизнесе (наличие \* цену продажи)

J – величина увеличения N1

V – доход от бизнеса

K – сумма кредита

NK – срок на который дали кредит. NK = NK – J

HH – флаг, банкрот ли национальный банк. 1– банкрот, 0 – не банкрот

S1 – процент, под который дали ссуду.

K1 – процент, под который взяли кредит

10 BORDER 7: PAPER 7: INK 9: POKE 23624,56: CLS : BEEP 1,1

20 GO TO 100

50 GO SUB 4110: INPUT " ЖЕЛАЕТЕ ЛИ ЕЩЕ РАЗ ПОПРОБОВАТЬ СВОИ СИЛЫ? ",XX

52 IF XX=1 THEN CLS : PRINT AT 8,6;" УДАЧИ ВАМ!!!": GO SUB 4110: CLS : GO TO 100

54 CLS : PRINT AT 8,6;"ДО СКОРОГО СВИДАНИЯ!!!": GO SUB 4110: NEW

100 POKE 23609,100

101 REM ПРЕЗИДЕНТ

102 REM 34014 БАЙТ

104 DIM D(10)

105 DIM C(10,10)

106 DIM O(10): DIM D(10): DIM T(10): DIM I(10): DIM L(10): DIM G(10): DIM Z(10): DIM P(10): DIM R(10): DIM S(10,10): DIM Q(10,10): DIM W(10): DIM E(10)

107 PRINT : PRINT " НА ВОПРОСЫ ОТВЕЧАТЬ: HET=0/ДА=1.": PRINT : PRINT

110 GO TO 4501

190 CLS : PRINT AT 8,10;"АВАРИЯ!!!": PRINT : GO TO 10

200 DEF FN R()=-1+2\*RND

210 LET Y=.01\*INT (5+47.5\*(1+FN R())): RETURN ***//Math.rnd [0;1)***

310 PRINT : PRINT " НЕ ПОНЯТНО. ПОВТОРИТЕ.": RETURN

410 INPUT "ПО РУКАМ?",X: IF (1-X)<0 THEN : GO SUB 310: GO TO 410

420 RETURN

510 INPUT " ( ПРОДАЖА=0/ПОКУПКА=1): ";X: INPUT " (ЧТО=N): ",Y: IF (X-1)<=0 THEN GO TO 530

520 GO SUB 310: GO TO 510

530 IF (5-Y)<0 THEN GO TO 520

532 RETURN

610 PRINT : PRINT " National Bank";

620 PRINT "-БАНКРОТ!": PRINT : PRINT : RETURN

710 INPUT "ЕЩЕ ОДНА СДЕЛКА? ";X: RETURN

810 INPUT " (УВОЛЬНЕНИЕ=0/НАЕМ=1): ";X: INPUT " (КОГО=N): ",Y: IF (X-1)<=0 THEN GO TO 830

820 GO SUB 310: GO TO 810

830 IF (5-Y)<0 THEN GO TO 820

840 RETURN

910 PRINT : PRINT " УЧТИТЕ НА БУДУЩЕЕ.": RETURN

920 PRINT : PRINT " УСВОИЛИ?": RETURN

1010 LET A=INT (A+.01): PRINT : PRINT : PRINT " НАЛИЧНЫЕ СРЕДСТВА ";A: PRINT : RETURN

1110 PRINT " КВАРТИРУ";: RETURN

1210 PRINT " МАШИНУ ";: RETURN

1310 PRINT " ВИЛЛУ ";: RETURN

1410 PRINT " ЯХТУ ";: RETURN

1510 PRINT " САМОЛЕТ ";: RETURN

1610 PRINT " БАР ";: RETURN

1710 PRINT " РЕСТОРАН";: RETURN

1810 PRINT " МАГАЗИН ";: RETURN

1910 PRINT " ОТЕЛЬ ";: RETURN

2010 PRINT " ЗАВОД ";: RETURN

2110 PRINT "ВЫ МОЖЕТЕ";: RETURN

2120 PRINT " КУПИТЬ ";: RETURN

2210 PRINT " ПРОДАТЬ ";: RETURN

2310 PRINT " ГОДОВОЙ": RETURN

2312 PRINT " ДОХОД";: RETURN

2410 PRINT " СТОИМОСТЬ";: RETURN

2510 PRINT " ЦЕНА ";: RETURN

2610 PRINT " МАКЛЕРА ";: RETURN

2710 PRINT " ВРАЧА ";: RETURN

2810 PRINT " АДВОКАТА ";: RETURN

2910 PRINT " ДЕТЕКТИВА ";: RETURN

3010 PRINT " ЛИЧНУЮ ОХРАНУ ";: RETURN

3110 PRINT " БИЗНЕСМЕН ": RETURN

3210 PRINT " ЛИДЕР ПРОФСОЮЗА ";: RETURN

3310 PRINT " ШЕРИФ ": RETURN

3410 PRINT " СЕНАТОР ": RETURN

3510 PRINT " ПРЕЗИДЕНТ ": RETURN

3610 LET J=0: FOR I=1 TO 5: LET J=J+C(3,I): NEXT I

3620 IF J<0 THEN GO TO 190

3625 IF J=0 THEN GO TO 3650

3630 PRINT "ВЫ ИМЕЕТЕ:"

3640 LET J=1010: FOR I=1 TO 5: LET J=J+100: IF (-(1-C(3,I))^2)<0 THEN GO TO 3650

3645 GO SUB J: PRINT

3650 NEXT I

3652 RETURN

3710 LET J=0: FOR I=1 TO 5: LET J=J+D(I): NEXT I

3720 IF J<0 THEN GO TO 190

3725 IF J=0 THEN GO TO 3750

3730 PRINT "ОПЛАЧИВАЕТЕ:"

3740 LET J=2510: FOR I=1 TO 5: LET J=J+100: IF (-(1-D(I))^2)<0 THEN GO TO 3750

3745 GO SUB J: PRINT

3750 NEXT I

3752 RETURN

3810 LET J=0: FOR I=1 TO 5: LET J=J+C(5,I): NEXT I

3820 IF J<0 THEN GO TO 190

3825 IF J=0 THEN GO TO 3850

3830 PRINT "В ВАШЕМ ВЛАДЕНИИ:"

3840 LET J=1510: FOR I=1 TO 5: LET J=J+100: IF (-(1-C(5,I))^2)<0 THEN GO TO 3850

3845 GO SUB J: PRINT

3850 NEXT I

3852 RETURN

3901 PRINT "В АКЦИЯХ ";INT (P)

3902 PRINT "СЧЕТ В БАНКЕ ";INT (H)

3903 PRINT "НЕДВИЖИМОСТЬ ";INT (C)

3904 PRINT "ДОХОДЫ ";INT (V)

3905 PRINT "РАСХОДЫ ";INT (U)

3906 IF K<=0 THEN GO TO 3910

3907 PRINT "КРЕДИТ ";INT (K+K\*K1)

3910 PRINT "ВЕСЬ КАПИТАЛ ";INT (A+P+H+C+V-U)

3920 RETURN

4010 PRINT "ВАМ ВСЕ ЯСНО?": RETURN

4110 FOR F=1 TO 40: LET FF=SQR (100): NEXT F: RETURN

4501 PRINT : PRINT : PRINT : PRINT : PRINT " ПРЕЗИДЕНТ ": PRINT : PRINT : PRINT : PRINT : PRINT : PRINT : PRINT

4502 LET N=0: LET H=10^6: LET B=1: LET K=0: LET S=0: LET C=0: LET NS=0: LET NK=0

4503 INPUT " ВАШ КЛАСС (1-3) ";L: IF (3-L)<0 THEN GO TO 4503

4504 PRINT : PRINT : PRINT : PRINT " ПОЗДРАВЛЯЕМ С ПРИБЫТИЕМ В НАШУ СТРАНУ,";

4505 PRINT "ГДЕ КАЖДЫЙ МОЖЕТ СТАТЬ ПРЕЗИДЕНТОМ!!!": PRINT : GO SUB 4110: CLS

4506 PRINT " МОЖНО ДАЖЕ ПРЕДСТАВИТЬ, ЧТО..."

4507 FOR I=1 TO 5: LET C(3,I)=1: LET C(5,I)=1: LET D(I)=1: NEXT I

4508 GO SUB 3605: GO SUB 3705: GO SUB 3810

4509 PRINT "И СЧЕТ В БАНКЕ ";H;: GO SUB 4110: PRINT ","

4510 PRINT "...НО ПОКА ЭТО МЕЧТЫ.": PRINT " РЕАЛИЗУЙТЕ ИХ!!!"

4511 DIM P(10): DIM G(10)

4512 LET H=0: FOR I=1 TO 5: LET C(3,I)=0: LET C(5,I)=0: LET D(I)=0: LET P(I)=0: LET G(I)=0: NEXT I

4513 INPUT " КАКОЙ СЕЙЧАС ГОД? ";NN

4514 INPUT "ВАШ ВОЗРАСТ?",N2: IF (N2-61)<0 THEN GO TO 4516

4515 CLS : PRINT AT 8,0;" В МУМИЯХ НЕ НУЖДАЕМСЯ!": GO TO 50

4516 IF (17-N2)<0 THEN GO TO 4518

4517 CLS : PRINT AT 8,0;" МЛАДЕНЦАМ У НАС ДЕЛАТЬ НЕЧЕГО!": GO TO 50

4518 GO SUB 210: LET N3=60+20\*Y: GO SUB 210: LET X=1500\*L\*(1+Y)

4520 INPUT "СКОЛЬКО ИМЕЕТЕ НАЛИЧНЫМИ? ";Y: IF (Y-X)<=0 THEN GO TO 4522

4521 LET Y=X\*2/3: PRINT : PRINT " ОТКУДА?!": PRINT " ПО НАШИМ ДАННЫМ У ВАС ";Y

4522 LET A=Y: LET K=0: LET S=0: LET P=0

4523 LET B3=0: GO SUB 210: LET N4=L+(5-L)\*Y: LET N1=0: LET U=0: LET V=.2: LET HH=0

4528 FOR I=1 TO 5: GO SUB 9910: LET S(3,I)=X: LET Q(3,I)=Z: NEXT I

4530 FOR I=1 TO 5: GO SUB 9910: LET S(5,I)=X: LET Q(5,I)=Z: LET W(I)=Z\*(Y-.3): NEXT I

4532 FOR I=1 TO 5: GO SUB 210: LET E(I)=4500\*Y+2000\*I: NEXT I

4536 GO SUB 1010

4540 PRINT " ЧТО ВАС ИНТЕРЕСУЕТ?": PRINT " 1-ФИНАНСОВОЕ ПОЛОЖЕНИЕ": PRINT " 2-ОБЩЕСТВЕННОЕ ПОЛОЖЕНИЕ": PRINT " 3-ЛИЧНОЕ ИМУЩЕСТВО": PRINT " 4-ПОДЧИНЕННЫЕ": PRINT " 5-БИЗНЕС": PRINT " 6-БИРЖА": PRINT " 7-БАНК": PRINT " 8-РАЗВЛЕЧЕНИЯ": PRINT : PRINT

4544 INPUT "(N)",M: LET M=INT (M): IF M<=0 THEN GO TO 4536

4545 IF (M-9)>=0 THEN GO SUB 310: GO TO 4544

4546 LET I=4501+500\*M: GO TO I

4710 IF (-NS)<0 THEN GO TO 4790

4712 IF S<0 THEN GO TO 4760

4713 IF S=0 THEN GO TO 4790

4720 PRINT : PRINT " ВЫ УДАЧНО ССУДИЛИ ДЕНЬГИ."

4730 PRINT " ПОЛУЧИТЕ СВОИ ";S;" И ": PRINT "БАРЫШ ";INT (S\*S1);".": PRINT : PRINT : LET A=A+S\*(1+S1): GO TO 4780

4760 PRINT : PRINT " ВАС НАДУЛИ СО ССУДОЙ.": PRINT "ПОТЕРЯНО-";S;".": PRINT : PRINT

4780 LET S=0

4790 RETURN

4810 IF (-NK)<0 THEN GO TO 4890

4812 IF K<=0 THEN GO TO 4880

4820 LET X=K+K\*K1: PRINT : PRINT " С ВАС УДЕРЖАЛИ КРЕДИТ ": PRINT "И %%: ";INT (X);".": PRINT : PRINT : GO SUB 7110

4880 LET K=0

4890 RETURN

4910 GO SUB 210: IF (Y-.2)<0 THEN GO TO 4930

4920 RETURN

4930 GO SUB 210: LET Y=INT (10\*Y): IF Y<=0 THEN GO TO 4920

4932 IF (5-Y)<0 THEN GO TO 4920

4934 IF (C(3,Y))<=0 THEN GO TO 4920

4936 LET X=Q(3,Y): LET J=4930+10\*Y: GO SUB J: IF (Y-5)<0 THEN GO TO 4990

4937 IF (Y-5)=0 THEN GO TO 4995

4940 PRINT : PRINT " ВАША КВАРТИРА СГОРЕЛА.": RETURN

4950 PRINT : PRINT " ВЫ ПОПАЛИ В АВТОКАТАСТРОФУ.": PRINT "ВЫБРОСЬТЕ ОСТАТКИ СВОЕГО АВТОМО-": PRINT "БИЛЯ!": RETURN

4960 PRINT : PRINT " СИОНИСТЫ ВЗОРВАЛИ ВАШУ ВИЛЛУ!": RETURN

4970 PRINT : PRINT " ЭКСТРЕМИСТЫ ЗАТОПИЛИ ВАШУ ЯХТУ!": RETURN

4980 PRINT : PRINT : PRINT " ВЫ РАЗБИЛИСЬ НА СВОЕМ САМОЛЕТЕ.": RETURN

4990 PRINT "НАНЕСЕН УЩЕРБ ";INT (X);"."

4992 LET C(3,Y)=0: LET Z=L(Y): IF Z<=0 THEN GO TO 4920

4994 PRINT "ВАМ ВЫПЛАЧИВАЕТСЯ СТРАХОВ-": PRINT "КА:";INT (Z);".": PRINT : PRINT : LET V=V+Z: LET L(Y)=0: RETURN

4995 GO TO 4110: CLS : PRINT AT 8,0;" ЛЕТАЙТЕ САМОЛЕТАМИ АЭРОФЛОТА!": PRINT

4996 PRINT : PRINT : PRINT " ГОСПОДА!": PRINT " БИЗНЕС ПОНЕС НЕВОСПОЛНИМУЮ УТРАТУ ": PRINT "УТРАТУ.";

4997 PRINT " НА ";N2;" ГОДУ ОБОРВАЛАСЬ": PRINT "ЖИЗНЬ НАШЕГО КОЛЛЕГИ."

4998 PRINT : PRINT " ПРИМИТЕ СОБОЛЕЗНОВАНИЯ.": PRINT : GO TO 50

5001 PRINT : PRINT : PRINT : PRINT " ГОД ";NN+N: GO SUB 1010

5003 LET P=0: LET C=0

5005 FOR I=1 TO 5: LET P=P+P(I)\*R(I): LET C=C+C(3,I)\*Q(3,I)+C(5,I)\*Q(5,I): NEXT I

5007 LET J=.1: GO SUB 5101: GO SUB 3901: PRINT : GO TO 5010

5009 LET J=.3: GO SUB 5101: GO TO 5012

5010 IF A<=0 THEN GO TO 5009

5012 GO SUB 4710: GO SUB 4810: GO SUB 4910: IF (N1-N4)<0 THEN GO TO 4540

5014 PRINT : PRINT : PRINT " ЗАКОНЧИЛСЯ ";NN+N;" ГОД.": PRINT : PRINT " ПОДВЕДЕМ ИТОГИ:": PRINT

5016 LET N=N+1: LET N2=N2+1: LET P=0: LET C=0: FOR I=1 TO 5: LET P=P+P(I)\*R(I): LET C=C+C(3,I)\*Q(3,I)+C(5,I)\*Q(5,I): NEXT I

5018 GO SUB 5810: PRINT : GO SUB 3610: GO SUB 3710: GO SUB 3810

5019 FOR I=1 TO 5: LET U=U+.5\*L(I): LET V=V+Z(I)\*P(I): IF (-G(I))<0 THEN GO TO 5021

5020 LET L(I)=0

5021 NEXT I

5022 GO SUB 1010: GO SUB 3901: INPUT " ОПЛАЧИВАЕМ РАСХОДЫ? ";Z

5023 IF (C(3,1)+C(3,3))<0 THEN GO TO 190

5024 IF (C(3,1)+C(3,3))>0 THEN GO TO 5030

5025 GO SUB 210: LET X=1000+20\*INT (Y\*ABS (A)/19):: LET A=A-X

5026 PRINT : PRINT " ЗА БРОДЯЖНИЧЕСТВО ШТРАФ:";INT (X);".": GO SUB 4010

5030 IF (1-Z)<=0 THEN GO TO 5040

5031 GO SUB 210: LET X=1000+25\*INT (Y\*ABS (A)/23): LET A=A-X

5032 PRINT : PRINT " ШТРАФ НАЛОГОВОГО УПРАВЛЕ-": PRINT "НИЯ:";INT (X);" ЗА ЖМОТНИЧЕСТВО!"

5040 LET A=A+V-U

5042 IF A<0 THEN GO TO 5050

5043 IF (N3-N2)<0 THEN GO TO 4996

5044 PRINT : PRINT : PRINT " НАСТУПИЛ ";NN+N;" ГОД!": PRINT

5048 GO TO 4523

5050 PRINT : PRINT " У ВАС ДЕФИЦИТ СРЕДСТВ:";-INT (A);"."

5051 IF H<=0 THEN GO TO 5053

5052 GO SUB 8211: GO TO 5042

5053 IF P<=0 THEN GO TO 5060

5054 GO SUB 210: LET X=P\*Y: LET A=A+X: LET P=0: FOR I=1 TO 5: LET P(I)=0: NEXT I

5055 PRINT : PRINT " ВАШИ АКЦИИ РАСПРОДАНЫ НА ": PRINT "СУММУ:";INT (X);"."

5056 IF A<0 THEN GO TO 5060

5057 GO TO 5043

5060 IF C<=0 THEN GO TO 5070

5061 GO SUB 210: LET X=C\*Y: LET A=A+X: LET C=0

5062 PRINT : PRINT " ИМУЩЕСТВО ПОШЛО СМОЛОТКА.": PRINT "ВЫРУЧЕНО:";INT (X);"."

5064 GO SUB 6610: FOR I=1 TO 5: LET C(3,I)=0: LET C(5,I)=0: NEXT I

5066 GO TO 5056

5070 GO SUB 6610: GO SUB 4110: LET X=1+INT (-.002\*A): IF (15-X)<0 THEN GO TO 5080

5071 LET N2=N2+X: LET B=1

5072 PRINT : PRINT : PRINT " ЗА ДОЛГИ ВЫ ПЕРЕЕЗЖАЕТЕ НА КА-": PRINT "ЗЕННУЮ ";

5073 PRINT "КВАРТИРУ В Fort Leveck ": PRINT "СРОКОМ НА ";INT (X);" ЛЕТ.": PRINT " ПОСИДИМ?"

5074 FOR I=1 TO X: PRINT " ГОД";NN+N: LET N=N+1: LET N1=0: LET J=N4: GO SUB 5101: GO SUB 4110: NEXT I

5075 GO SUB 210: LET A=1000\*L\*(1+Y)

5076 PRINT : PRINT " ВАМ ВЫДАЛИ ПОДЪЕМНЫЕ:";INT (A);"."

5077 PRINT : PRINT " ПОЛУЧИЛИ УРОК?": GO TO 5043

5080 PRINT : PRINT : PRINT : PRINT " ЗА ОГРОМНЫЕ ДОЛГИ ВЫ ПРИГОВОРЕ-": PRINT "НЫ К ВЫСШЕЙ МЕРЕ...": GO TO 4996

5101 IF (N4-N1)<=0 THEN GO TO 5110

5102 LET N1=N1+J: IF (N1-N4)>=0 THEN LET J=J+N4-N1

5103 LET J=J/N4: GO SUB 5210: LET UU=500\*(2+B^2+FN R()): LET VV=0: FOR W=1 TO 5: LET UU=UU+.45\*C(3,W)\*Q(3,W)+D(W)\*E(W): LET VV=VV+C(5,W)\*W(W): NEXT W

5105 LET U=U+J\*UU: LET V=V+J\*VV: LET VV=LN (1+.02\*B): LET H=H\*EXP (J\*VV)

5110 RETURN

5210 LET NK=NK-J: LET NS=NS-J: FOR W=1 TO 5: LET G(W)=G(W)-J: NEXT W: RETURN

5301 IF (-(S\*S))<0 THEN GO TO 5350

5330 PRINT " 4-ДАТЬ ССУДУ"

5350 RETURN

5501 LET J=.3: GO SUB 5101: IF B3<0 THEN GO TO 190

5502 IF B3=0 THEN GO TO 5510

5504 PRINT : PRINT " У ВАС СКЛЕРОЗ.": GO SUB 4110: GO TO 5010

5510 GO SUB 5810: LET B3=1: IF (2\*INT (.5\*N+.1)-N)<0 THEN GO TO 5710

5512 LET J=.7: GO SUB 5101: GO SUB 1010: LET I=B+1: GO SUB 9910: LET I=I\*100: LET Y=0

5514 FOR J=1 TO 5: LET Y=Y+.5\*(C(3,J)+C(5,J))+2\*D(J): NEXT J

5516 LET J=Y/(5\*I/100): IF (J-1)<0 THEN GO TO 5520

5518 LET J=1

5520 PRINT " ПРИМИТЕ УЧАСТИЕ В ВЫБОРАХ."

5522 LET II=3010+I: PRINT "ИЗБИРАЕТСЯ ";: GO SUB II: IF (2-I/100)<0 THEN GO TO 5524

5523 PRINT "МУ- СОРЩИКОВ."

5524 PRINT "КАМПАНИЯ ОБОЙДЕТСЯ В ";X;".": PRINT " ВЕРОЯТНОСТЬ УСПЕХА ";INT (100\*J);"%"

5528 INPUT " УЧАСТВУЕТЕ В ВЫБОРАХ? ";Y: IF (Y-1)<0 THEN GO TO 5610

5530 GO SUB 210: IF (X-A-H)<0 THEN GO TO 5540

5532 GO SUB 7310: GO TO 7210

5540 GO SUB 7110: IF (J-Y)<0 THEN GO TO 5550

5542 PRINT : PRINT " ПОЗДРАВЛЯЕМ ВАС!": PRINT " ТЕПЕРЬ ВЫ ";: GO SUB II: PRINT : LET B=I/100: IF (B-5)<0 THEN GO TO 7220

5544 PRINT : PRINT : PRINT : PRINT " ВЫ ДОСТИГЛИ НЕВОЗМОЖНОГО": PRINT : GO TO 50

5550 PRINT : PRINT " ВЫ НАБРАЛИ ТОЛЬКО ";INT (50\*(1-Y));"% ГОЛОСОВ."

5610 PRINT : PRINT "СЛЕДУЮЩИЕ ВЫБОРЫ ЧЕРЕЗ ДВА ГОДА.": GO TO 7220

5710 PRINT : PRINT " В ЭТОМ ГОДУ ": PRINT " ВЫБОРЫ НЕ ПРОВОДЯТСЯ.": GO TO 7210

5810 PRINT " В НАСТОЯЩЕЕ ВРЕМЯ": PRINT " BЫ ";: LET I=3010+B\*100: GO SUB I: RETURN

6001 LET JJ=0

6002 LET J=1: GO SUB 5101

6003 GO SUB 1010: LET J=0: FOR I=1 TO 5: LET J=J+C(M,I): NEXT I

6004 IF J<0 THEN GO TO 190

6005 IF J=0 THEN GO TO 6014

6006 GO SUB 2110: PRINT : GO SUB 2210: GO SUB 2410: IF (M-4)>=0 THEN GO SUB 2310: GO SUB 2312

6007 PRINT : LET II=1010+JJ

6008 FOR I=1 TO 5: LET II=II+100: IF (C(M,I)-1)>=0 THEN GO SUB 6110

6010 NEXT I

6011 IF (4-J)<0 THEN GO TO 6030

6012 PRINT

6014 IF (4-J)<0 THEN GO TO 6030

6015 GO SUB 2110: PRINT : GO SUB 2120: GO SUB 2510: IF (M-4)>=0 THEN GO SUB 2310: GO SUB 2312

6016 PRINT : LET II=1010+JJ: FOR I=1 TO 5: LET II=II+100: IF (-C(M,I))>=0 THEN GO SUB 6210

6020 NEXT I

6021 IF (4-M)>=0 THEN PRINT : PRINT " РАСХОДЫ НА СОДЕРЖАНИЕ:45% СТОИМОСТИ В ГОД."

6030 GO SUB 510: IF X<0 THEN GO TO 5010

6031 IF X=0 THEN GO TO 6050

6032 IF (C(M,Y))<0 THEN GO TO 190

6033 IF (C(M,Y))=0 THEN GO TO 6040

6034 PRINT : PRINT : PRINT " НЕ ГЛУПИТЕ ";: LET II=3010+B\*100: GO SUB II: GO TO 7210

6040 IF (A-S(M,Y))<0 THEN GO TO 7230

6042 LET A=A-S(M,Y): LET C(M,Y)=1

6044 GO SUB 710: IF (X-1)<0 THEN GO TO 7220

6045 IF (X-1)=0 THEN GO TO 6003

6046 GO SUB 310: GO TO 6044

6050 IF Y<0 THEN GO TO 5010

6051 IF Y=0 THEN GO TO 7220

6052 IF (C(M,Y)-1)<0 THEN GO TO 7240

6054 LET A=A+Q(M,Y): LET C(M,Y)=0: GO TO 6044

6110 GO SUB 6310: PRINT " ";Q(M,I);: GO SUB 6410: PRINT : RETURN

6210 GO SUB 6310: PRINT " ";S(M,I);: GO SUB 6410: PRINT : RETURN

6310 PRINT I;" ";: GO SUB II: PRINT " ";: RETURN

6410 IF (M-4)>=0 THEN PRINT " ";INT (W(I));

6420 RETURN

6501 LET J=1: GO SUB 5101

6502 GO SUB 1010

6503 IF (D(1)+D(2)+D(3)+D(4))<0 THEN GO TO 190

6504 IF (D(1)+D(2)+D(3)+D(4))=0 THEN GO TO 6520

6505 GO SUB 2110: PRINT : PRINT " УВОЛИТЬ,ЗАПЛАТИВ НЕУСТОЙКУ "

6506 LET II=2510: FOR I=1 TO 5: LET II=II+100: IF (D(I))>0 THEN PRINT I;" ";: GO SUB II: PRINT " ";2\*E(I)

6508 IF D(I)<0 THEN GO TO 190

6509 IF D(I)=0 THEN GO TO 6510

6510 NEXT I

6520 IF (5-D(1)-D(2)-D(3)-D(4)-D(5))<0 THEN GO TO 190

6521 IF (5-D(1)-D(2)-D(3)-D(4)-D(5))=0 THEN GO TO 6540

6525 PRINT : GO SUB 2110: PRINT " НАНЯТЬ,УПЛАТИВ В ГОД "

6527 LET II=2510: FOR I=1 TO 5: LET II=II+100: IF (-D(I))>=0 THEN PRINT I;" ";: GO SUB II: PRINT " ";E(I)

6530 NEXT I

6540 GO SUB 810: IF X<0 THEN GO TO 6540

6541 IF X=0 THEN GO TO 6560

6542 IF Y<=0 THEN GO TO 6590

6544 IF (1-D(Y))<0 THEN GO TO 190

6545 IF (1-D(Y))=0 THEN GO TO 6034

6546 LET J=INT ((1-N1/N4)\*E(Y)\*.01): IF J<=0 THEN GO TO 6550

6547 LET J=50\*J: PRINT : PRINT " ABAHC ";J: IF (A-J)<0 THEN GO TO 6580

6548 INPUT " ВЫПЛАЧИВАЕТЕ? ";X: IF (X-1)<>0 THEN GO TO 6592

6549 LET A=A-J: LET E(Y)=E(Y)-J

6550 LET D(Y)=1: PRINT : PRINT " ДОГОВОР ОФОРМЛЕН."

6552 GO SUB 710: IF (X-1)<>0 THEN GO TO 7220

6553 IF (X-1)=0 THEN GO TO 6502

6560 IF Y<0 THEN GO TO 6590

6561 IF Y=0 THEN GO TO 7220

6562 IF (D(Y))<0 THEN GO TO 190

6563 IF D(Y)=0 THEN GO TO 6034

6564 LET A=A-2\*E(Y): LET D(Y)=0: PRINT : PRINT " ДОГОВОР РАСТОРГНУТ."

6566 IF (-A)<0 THEN GO TO 6552

6567 IF (-A)=0 THEN GO TO 7220

6568 LET U=U-A: LET A=0: GO TO 7220

6580 PRINT : GO SUB 7310: GO TO 7210

6590 PRINT : PRINT " ВЫ РЕХНУЛИСЬ?": GO TO 6502

6592 PRINT : PRINT " КАК ХОТИТЕ, ДЕЛО ВАШЕ!": GO TO 7220

6610 IF (D(1)+D(2)+D(3)+D(4)+D(5))<0 THEN GO TO 190

6611 IF (D(1)+D(2)+D(3)+D(4)+D(5))=0 THEN GO TO 6660

6620 FOR I=1 TO 5: LET D(I)=0: NEXT I

6630 PRINT : PRINT " ПОДЧИНЕННЫЕ ВАС БРОСИЛИ!"

6660 RETURN

6702 GO SUB 210: LET Y=INT (10\*Y): IF (-Y)<0 THEN GO TO 6712

6710 RETURN

6712 IF (5-Y)<0 THEN GO TO 6710

6713 IF (5-Y)=0 THEN GO TO 6785

6714 IF (-D(Y))<0 THEN GO TO 6710

6716 LET J=6700+20\*Y: GO SUB 210: LET X=(A+200)\*Y: GO TO J

6720 IF P<=0 THEN GO TO 6738

6722 PRINT : PRINT " ВЫ НЕПРАВИЛЬНО ОФОРМЛЯЛИ СДЕЛКИ."

6724 PRINT "УБЫТОК:";INT (X);".": PRINT : PRINT " ЗАВЕДИТЕ МАКЛЕРА.": GO SUB 7110

6738 RETURN

6740 PRINT : PRINT " ВЫ ЗАБЫВАЕТЕ О ЗДОРОВЬЕ.": LET X=X+400

6742 PRINT "ПРЕБЫВАНИЕ В БОЛЬНИЦЕ ОБОШЛОСЬ": PRINT "ВАМ В ";INT (X): GO SUB 7110: RETURN

6760 PRINT : PRINT " ФИРМА <IBM> ПРЕДЪЯВИЛА ВАМ ": PRINT "ИСК В ";INT (X);".": LET Y=15\*INT (X\*.02)

6762 PRINT " УСЛУГИ АДВОКАТА ОБОЙДУТЬСЯ ": PRINT "В ";INT (Y);"."

6764 PRINT "ВЕРОЯТНОСТЬ УСПЕХА 65%": INPUT " НАНИМАЕТЕ? ";Z

6766 IF (-Z)<0 THEN GO TO 6770

6767 PRINT : PRINT " ИСК <IBM> К ВАМ УДОВЛЕТВОРЕН.": PRINT "ВЫ ПОТЕРЯЛИ ";INT (X);".": GO SUB 7110: RETURN

6770 IF (.65-FN R())<0 THEN GO TO 6775

6771 PRINT : PRINT " <IBM> ВЫПЛАЧИВАЕТ НЕУСТОЙ-": PRINT "КУ ";INT (2\*Y);".": LET V=V+Y

6772 PRINT : PRINT " ИМЕЙТЕ СВОЕГО АДВОКАТА!": RETURN

6775 PRINT : PRINT " УВЫ. ДЕЛО ПРОИГРАНО.": LET U=U+X: LET X=Y: GO SUB 7110: GO TO 6772

6780 PRINT : PRINT " ВАС ШАНТАЖИРУЮТ, ВЫМОГАЯ ";INT (X);".": GO SUB 7110

6782 PRINT "ОБРАЩАЙТЕСЬ К УСЛУГАМ СЫСКНОГО ": PRINT "БЮРО."

6784 PRINT " ПРИДЕТСЯ ПЛАТИТЬ!": RETURN

6785 IF (-D(5))<0 THEN GO TO 6710

6786 PRINT : PRINT " У ВАС УКРАЛИ ВСЕ ЦЕННЫЕ БУМАГИ..": GO SUB 210

6787 PRINT "УБЫТОК ";INT (X): LET I=10\*INT (45\*Y+80+.03\*X)

6788 PRINT " СЫСКНОЕ БЮРО ПРЕДЛАГАЕТ СВОИ ": PRINT "УСЛУГИ ЗА ";INT (I);"."

6789 PRINT " ШАНС ПОИМКИ ВОРОВ ";INT (Y\*100);"%": INPUT " ДОГОВОРИЛИСЬ? ";X: IF (-X)<0 THEN GO TO 6792

6790 LET P=0: FOR I=1 TO 5: LET P(I)=0: NEXT I

6791 RETURN

6792 IF (FN R()-Y)<0 THEN GO TO 6796

6793 PRINT : PRINT " ВОРЫ ПОКИНУЛИ НАШУ СТРАНУ.": LET Y=450\*Y+800

6795 PRINT "ВЗЫСКИВАЕМ ТОЛЬКО НАКЛАДНЫЕ РАСХОДЫ ";INT (Y): LET U=U+Y: GO SUB 910: GO TO 6790

6797 PRINT : PRINT " ВОРЫ ПОЙМАНЫ!": LET U=U+I: RETURN

7001 LET JJ=500: GO TO 6002

7110 LET A=A-X: IF A<0 THEN GO TO 7120

7115 RETURN

7120 LET U=U-A: LET A=0: RETURN

7210 PRINT : PRINT " УСВОИЛИ?"

7220 GO SUB 1010: GO TO 5010

7230 GO SUB 7310: GO TO 7210

7240 GO SUB 7410: GO TO 7210

7310 PRINT " ВЫ НЕ ИМЕЕТЕ ТРЕБУЕМОЙ СУММЫ НАЛИЧНЫМИ."

7320 LET X=1500+50\*INT (10\*FN R())

7330 PRINT "ЗА МОШЕННИЧЕСТВО ШТРАФ:";INT (X)

7340 GO SUB 7110: RETURN

7410 PRINT : PRINT " ВАМ НЕЧЕГО ПРОДАВАТЬ!"

7420 GO SUB 7320: GO SUB 7110: RETURN

7501 LET J=.4: GO SUB 5101: IF (N1-N4)<0 THEN GO TO 7505

7503 PRINT : PRINT " КОНЕЦ ГОДА-БИРЖА ЗАКРЫЛАСЬ.": GO TO 7220

7505 LET X=0: FOR I=1 TO 5: LET X=X+P(I)\*R(I): NEXT I

7507 IF X<0 THEN GO TO 190

7508 IF X>0 THEN GO SUB 6702

7510 LET J=.6: GO SUB 5110: FOR I=1 TO 5: GO SUB 210: LET R(I)=100\*Y: LET O(I)=0: GO SUB 210: LET Z(I)=20\*Y: NEXT I

7520 GO SUB 1010: PRINT

7521 PRINT "АКЦИИ ФИРМЫ ИМЕЕТЕ КУРС ДИВИДЕН-"

7522 PRINT " ТЫ (%) "

7523 LET J=7900: FOR I=1 TO 5: LET J=J+10: PRINT I;" ";: GO SUB J: PRINT " ";P(I);" ";R(I);" ";Z(I): NEXT I

7524 PRINT : PRINT : PRINT

7525 INPUT " (ПРОДАЖА=0/ПОКУПКА=1): ";X: INPUT " (ФИРМЫ=M): ",I: INPUT " (КОЛИЧЕСТВО=N): ";M

7527 IF X<0 THEN GO TO 7220

7528 IF X=0 THEN GO TO 7540

7529 LET X=1: IF (-I)<0 THEN GO TO 7531

7530 GO SUB 310: GO TO 7525

7531 IF (5-I)<0 THEN GO TO 7530

7532 LET M=INT (ABS (M)): IF X<0 THEN GO TO 7550

7533 IF (M\*R(I)-A-.1)<0 THEN GO TO 7553

7535 GO SUB 7310: GO SUB 910: GO TO 7220

7540 IF I<0 THEN GO TO 7530

7541 IF I=0 THEN GO TO 7220

7542 LET X=-1: GO TO 7531

7550 IF (M-P(I)-.1)<0 THEN GO TO 7560

7551 GO SUB 7410: GO SUB 910: GO TO 7220

7553 LET Z=R(I)\*5\*(B+2\*D(1)): IF (O(I)+M-Z-.1)<0 THEN GO TO 7570

7557 LET M=Z-O(I): PRINT " УДАЛОСЬ СКУПИТЬ ";M: GO TO 7570

7560 LET Z=(105-R(I))\*5\*(B+2\*D(1)): IF (M-O(I)-Z-.1)<0 THEN GO TO 7570

7567 LET M=Z+O(I): PRINT " УДАЛОСЬ РЕАЛИЗОВАТЬ ";M: GO TO 7570

7570 LET M=M\*X: IF (-(M\*M))>=0 THEN PRINT : PRINT " У НАС ДУРАКОВ НЕТ!"

7571 LET P(I)=INT (P(I)+.1+M): LET O(I)=O(I)+M: LET A=A-R(I)\*M

7573 IF (N4-N1-.1)<0 THEN GO TO 7503

7575 GO SUB 710: IF X<=0 THEN GO TO 7220

7576 IF X>0 THEN GO TO 7520

7910 PRINT "Standart Oil ";: RETURN

7920 PRINT "Stell Company";: RETURN

7930 PRINT "IBM ";: RETURN

7940 PRINT "Suzuki ";: RETURN

7950 PRINT "Krust & Co ";: RETURN

8001 IF HH<0 THEN GO TO 190

8002 IF HH=0 THEN GO TO 8004

8003 GO SUB 610: GO TO 5010

8004 IF (FN R()-.97)<0 THEN GO TO 8007

8005 GO SUB 610: LET HH=1: LET NK=N4-N1: IF H=0 THEN GO TO 5010

8006 LET X=.1\*H: LET A=A+H: PRINT : PRINT " ВАМ ВЫПЛАЧЕНА КОМПЕНСАЦИЯ ";INT (X): LET H=0: GO TO 7220

8007 PRINT : PRINT : PRINT : PRINT " National Bank": PRINT " ПРИВЕТСТВУЕТ КЛИЕНТА!": LET J=1: GO SUB 5101

8008 PRINT : PRINT " ЧТО ЖЕЛАЕТЕ?": PRINT " 1-ЗАСТРАХОВАТЬ ИМУЩЕСТВО": PRINT " 2-СДЕЛАТЬ ВКЛАД"

8009 PRINT " 3-СНЯТЬ СО СЧЕТА": GO SUB 5301: GO SUB 8401: INPUT " [N] ",X: GO TO 8101

8010 IF (C(3,1)+C(3,2)+C(3,3)+C(3,4)+C(3,5))<0 THEN GO TO 190

8011 IF (C(3,1)+C(3,2)+C(3,3)+C(3,4)+C(3,5))=0 THEN GO TO 8090

8012 PRINT : PRINT : PRINT " МОЖЕТЕ НА СУММУ": PRINT " ЗАСТРАХОВАТЬ НЕ БОЛЕЕ:"

8014 LET J=1010

8016 FOR I=1 TO 5: LET J=J+100: IF (C(3,I))<0 THEN GO TO 190

8017 IF C(3,I)>0 THEN PRINT I;" ";: GO SUB J: PRINT " ";Q(3,I)

8018 NEXT I

8020 PRINT : PRINT " ПРИ ГОДОВЫХ ВЗНОСАХ 5%"

8022 INPUT " [СТРАХУЕМ ЧТО=N]: ";X: INPUT " [НА СРОК=T]: ",Y

8024 IF X<=0 THEN GO TO 7220

8026 IF C(3,X)<0 THEN GO TO 190

8027 IF C(3,X)=0 THEN GO TO 8092

8028 INPUT " НА СУММУ ";J: LET J=ABS (J): IF (J-Q(3,X))<=0 THEN GO TO 8040

8030 PRINT : PRINT " БОЛЕЕ ЧЕМ НА СТОИМОСТЬ НЕ СТРАХУЕМ.": GO TO 7210

8040 LET G(X)=INT (ABS (Y)): LET L(X)=J

8041 INPUT " ЕЩЕ СТРАХОВКА? ";X: IF (X-1)<0 THEN GO TO 8008

8042 IF (X-1)=0 THEN GO TO 8022

8043 IF (X-1)>0 THEN GO TO 7220

8090 PRINT : PRINT " ВЫМ НЕЧЕГО СТРАХОВАТЬ!": GO TO 8407

8092 PRINT : PRINT " ВЫ ОШИБЛИСЬ.": GO TO 8010

8101 LET X=INT (X): IF X<=0 THEN GO TO 7220

8102 IF (X-6)<0 THEN GO TO 8104

8103 GO SUB 310: GO TO 8008

8104 IF S=0 THEN GO TO 8107

8105 IF (X-4)<0 THEN GO TO 8109

8106 IF (X-4)=0 THEN GO TO 8407

8107 IF K<=0 THEN GO TO 8109

8108 IF (X-5)=0 THEN GO TO 8407

8109 LET X=7910+X\*100: GO TO X

8110 PRINT : GO SUB 1010: PRINT " ГАРАНТИРУЕМ ДОХОД ";2\*B;"% B ГОД.": GO SUB 8115: GO TO 8120

8115 PRINT "СТОИМОСТЬ ОПЕРАЦИИ 5%": RETURN

8120 INPUT " СКОЛЬКО ПОМЕЩАЕТЕ? ";X: LET X=ABS (X): IF (X-A)<=0 THEN GO TO 8140

8130 GO SUB 7310: GO TO 7210

8140 LET A=A-X: LET H=H+.95\*X

8150 GO TO 8008

8210 GO SUB 8211: GO TO 8150

8211 LET H=INT (.5+H): PRINT : PRINT " СЧЕТ В БАНКЕ ";H: GO SUB 8115

8220 INPUT " СКОЛЬКО БЕРЕТЕ? ";X: LET X=ABS (X): IF (X-H)<=0 THEN GO TO 8240

8230 PRINT : PRINT " ВНИМАТЕЛЬНЕЕ НАДО!": GO TO 8210

8240 LET H=H-X: LET A=A+.95\*X: RETURN

8310 PRINT : PRINT : GO SUB 1010: PRINT " ДОГОВОРИМСЯ ОБ УСЛОВИЯХ."

8312 INPUT " СКОЛЬКО ДАДИТЕ? ";S: LET S=ABS (S): IF (S-A)<=0 THEN GO TO 8320

8314 PRINT : PRINT " ВЫ НЕ ИМЕЕТЕ ТРЕБУЕМОЙ СУММЫ НАЛИЧНЫМИ.": LET S=0: GO TO 7220

8320 INPUT " НА КАКОЙ СРОК? ";NS: LET NS=ABS (NS): LET J=SQR (SQR (NS)): IF (NS-11)<0 THEN GO TO 8340

8330 PRINT : PRINT " ЭК ЗАГНУЛИ!": GO TO 8320

8340 INPUT " ПОД КАКИЕ ПРОЦЕНТЫ? ";S1: LET S1=.01\*ABS (S1): LET Y=32.94\*J/(.6+S1)

8345 PRINT : PRINT " ШАНС ЗАРАБОТАТЬ:";INT (Y);"%": GO SUB 410: IF X<=0 THEN GO TO 8370

8350 LET A=A-S: LET X=Y/100: GO SUB 210: IF (Y-X)<0 THEN GO TO 8150

8355 LET S=-S: GO TO 8150

8370 LET S=0: GO TO 6592

8401 IF (-K)<0 THEN GO TO 8405

8403 PRINT " 5-ПОЛУЧИТЬ КРЕДИТ "

8405 RETURN

8407 PRINT : PRINT " ПРОСИМ НЕЗАМЕДЛИТЕЛЬНО ПОКИНУТЬ БАНК!": GO TO 7210

8410 GO SUB 1010: LET Y=A+H+P+C-U+V: IF (-Y)<0 THEN GO TO 8420

8412 PRINT : PRINT : PRINT " БАНКРОТАМ НЕ ДАЕМ.": GO TO 7210

8420 PRINT : PRINT : PRINT " СО ВСЕМИ ПОТРОХАМИ ВЫ СТОИ-": PRINT "ТЕ:";INT (Y);"."

8422 PRINT "ДАЕМ НА СРОК НЕ БОЛЕЕ 5 ЛЕТ.": INPUT " СКОЛЬКО? ";K: LET K=ABS (K)

8424 INPUT " СРОК? ";NK: IF (NK-6)<0 THEN GO TO 8430

8426 PRINT : PRINT " ЧИТАТЬ НЕ УМЕЕТЕ?": GO TO 8424

8430 LET K1=.01+(3+FN R())\*K\*NK/Y/(L+2)/5

8432 PRINT : PRINT " ДАЕМ ПОД ";INT (K1\*100);"%": INPUT " БЕРЕТЕ? ";X: IF (-X)<0 THEN GO TO 8440

8434 LET K=0: GO TO 8008

8440 PRINT : PRINT " ЗАПОМНИТЕ, ВРЕМЯ РАСПЛАТЫ:";NN+N+NK;".": LET A=A+K: GO TO 8150

8501 LET J=2.5: GO SUB 5101

8503 FOR I=1 TO 5: GO SUB 9910: LET T(I)=X: LET I(I)=T(I)\*(2-Y): LET O(I)=100\*Y: NEXT I

8505 GO SUB 1010: PRINT " РАЗВЛЕКАЯСЬ С УМОМ, МОЖНО ПОЛУ-": PRINT "ЧИТЬ И БАРЫШ.": PRINT

8510 PRINT " МОЖЕМ ЗАТ- ВОЗМ-НЫЙ ВЕР-ТЬ"

8511 PRINT "ПРЕДЛОЖИТЬ РАТЫ ДОХОД УСПЕХА(%)": PRINT

8513 LET J=8900: FOR I=1 TO 5: LET J=J+10: PRINT I;" ";: GO SUB J: PRINT " ";T(I);" ";INT (I(I));" ";O(I): NEXT I

8515 INPUT " ГУЛЯЕМ? ";X: IF (-X)<0 THEN GO TO 8520

8517 PRINT : PRINT " ВЫ ЖМОТ?!": GO TO 7220

8520 INPUT " ЧЕГО ИЗВОЛИТЕ-C? ";X: IF (-X)<0 THEN GO TO 8523

8521 PRINT : PRINT " ПРОТРЕЗВЕЛ БЫ СНАЧАЛА...": GO TO 7220

8523 IF (5-X)<0 THEN GO TO 8521

8525 IF (T(X)-A-H)<=0 THEN GO TO 8530

8527 GO SUB 7310: GO TO 7210

8530 GO SUB 210: IF (100\*Y-O(X))<=0 THEN GO TO 8540

8533 PRINT : PRINT " ВАМ НЕ ВЕЗЕТ-ОДНИ РАСХОДЫ.": LET X=T(X): GO SUB 7110

8534 IF A<0 THEN GO TO 7210

8535 IF A=0 THEN GO TO 7220

8536 INPUT " ЕЩЕ ПОДРАЗВЛЕЧЕМСЯ? ";X: IF X<=0 THEN GO TO 7220

8537 GO TO 8505

8540 PRINT : PRINT : PRINT " ВАМ ПОДФАРТИЛО.ДОВОЛЬНЫ?"

8543 LET A=A-T(X)+I(X): GO TO 7220

8910 PRINT "ПРЕФЕРАНС ";: RETURN

8920 PRINT "МОНТЕ-КАРЛО";: RETURN

8930 PRINT "ЛЮБОВНИЦУ ";: RETURN

8940 PRINT "БАНКЕТ ";: RETURN

8950 PRINT "КРУИЗ ";: RETURN

9910 GO SUB 210: LET X=INT ((2+5\*Y)\*20\*5^I): LET Z=INT (.7\*X\*(Y+.3)): RETURN

9911 BORDER BIN : PAPER BIN : INK BIN : POKE 23624,BIN : IF PEEK 23635=203 THEN LOAD ""CODE : GO TO 1

9912 RANDOMIZE USR 15619: REM : LOAD "PREZIUDG"CODE

9913 GO TO 1